#!/usr/local/cpanel/3rdparty/bin/perl
# cpanel - scripts/rpmup Copyright 2021 cPanel, L.L.C.
# All rights reserved.
# copyright@cpanel.net http://cpanel.net
# This code is subject to the cPanel license. Unauthorized copying is prohibited
#
# This script effectively does a yum -y update
# Only update methods for RHEL 4-6 are supported
package scripts::rpmup;
use cPstrict;
use Cpanel::Imports;
use Cpanel::Config::Httpd::EA4 ();
use Getopt::Param ();
use Cpanel::Update::Config ();
use Cpanel::SysPkgs ();
use Cpanel::Config::LoadCpConf ();
use Cpanel::ServerTasks ();
my @EA4_REQUIRED_RPMS = qw( ea-apache24 ea-apache24-config );
unless ( caller() ) {
exit( __PACKAGE__->script(@ARGV) );
}
sub script {
my $param = Getopt::Param->new;
my $forced = $param->get_param('force') || $ENV{'FORCEDCPUPDATE'};
my $os_updates_enabled = are_os_updates_enabled( $param->get_param('verbose') // 0 );
if ( !$os_updates_enabled ) {
# return 1 will exit 1 if ensure_ea4_is_updated fails
return 1 if !update_ea4_only();
return 0;
}
my $rpmup_allow_kernel = Cpanel::Config::LoadCpConf::loadcpconf_not_copy()->{'rpmup_allow_kernel'} // 0;
my $syspkgs = Cpanel::SysPkgs->new();
_run_checkyum( $syspkgs, !$rpmup_allow_kernel );
if ($forced) {
say 'Running package manager clean up before update due to force option ...';
$syspkgs->clean();
}
# The $syspkgs object will have already notified about the error.
# We do not die on failure in case _run_checkyum needs to
# change the kernel exclude back below
my $syspkgs_update_success = $syspkgs->update();
Cpanel::ServerTasks::schedule_task( ['SystemTasks'], 5, "recache_system_reboot_data" );
if ( !$rpmup_allow_kernel ) {
# Only call checkyum to put back the kernel exclude
# if we took it out above.
_run_checkyum( $syspkgs, $rpmup_allow_kernel );
}
return $syspkgs_update_success ? 0 : 1;
}
sub are_os_updates_enabled ($verbose) {
my $update_conf_ref = Cpanel::Update::Config::load();
return 1 if $update_conf_ref->{'RPMUP'} ne 'never';
my $updates_setting = $update_conf_ref->{'UPDATES'} || '';
my $is_manual = $ENV{'CPANEL_IS_CRON'} ? 0 : 1; # see upcp for how this is set
my $is_ea4 = Cpanel::Config::Httpd::EA4::is_ea4();
if ( $updates_setting eq 'never' ) {
if ( $is_ea4 && $verbose ) {
print locale->maketext(
'Because both the “[_1]” and “[_2]” options are set to “[_3]”, the system will not perform any [asis,RPM] updates.',
'RPMUP',
'UPDATES',
'never'
) . "\n";
print locale->maketext(
'Change “[_1]” to a different value to enable all [asis,RPM] updates, or change “[_2]” to a different value to enable updates to just [asis,EasyApache 4].',
'RPMUP',
'UPDATES'
) . "\n";
}
}
elsif ( $updates_setting eq 'manual' && !$is_manual ) {
# Although cPanel updates are enabled, one is not happening
# at this time because the ENV variable CPANEL_IS_CRON is set
# to 1 which indicates upcp was not called manually so only
# maintenance is being run and there is no concern about
# EA4 not being in sync with cPanel. When we are doing
# a manually update we will fall into the block below and
# and update EA4 if its installed.
if ($verbose) {
print locale->maketext(
"Because the “[_1]” option is set to “[_2]”, the system will not update any [asis,RPMs].",
'RPMUP',
'never'
) . "\n";
}
if ( $is_ea4 && $verbose ) {
print locale->maketext(
"Because the “[_1]” option is set to “[_2]” and this is an automatic update, the system will not update EasyApache 4.",
'UPDATES',
'manual'
) . "\n";
}
}
else {
# In the event OS updates are disabled, we need to manually
# request an EA4 update to prevent the system from breaking
# because EA4 is out of date and cPanel has a newer
# configuration.
if ($is_ea4) {
if ($verbose) {
print locale->maketext(
"Because [asis,cPanel] automatic updates are enabled and the “[_1]” option is set to “[_2]”, the [asis,RPM] update will only apply to EasyApache 4. This ensures that [asis,cPanel] and EasyApache 4 remain compatible.",
'RPMUP',
'never'
) . "\n";
}
}
elsif ($verbose) {
print locale->maketext(
"Because the “[_1]” option is set to “[_2]”, the system will not update any [asis,RPMs].",
'RPMUP',
'never'
) . "\n";
}
}
return 0;
}
sub update_ea4_only () {
return Cpanel::SysPkgs->new->update( 'pkglist' => \@EA4_REQUIRED_RPMS );
}
sub _run_checkyum ( $syspkgs, $kernel ) {
my %exclude_options = %Cpanel::SysPkgs::DEFAULT_EXCLUDE_OPTIONS;
$exclude_options{'kernel'} = $kernel ? 1 : 0;
$syspkgs->reinit( \%exclude_options );
if ( !$syspkgs->check() ) {
die "The system failed to parse the yum.conf file.";
}
return 1;
}
Mini Shell